unity package structure

Assets/ru.chikalin.textdecal/Shaders/LiberationSans Decals SDF 1.asset.meta

@@ -0,0 +1,8 @@
+fileFormatVersion: 2
+guid: f84ba4af5f59a4e5db5d23c9c3580b8c
+NativeFormatImporter:
+  externalObjects: {}
+  mainObjectFileID: 11400000
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/ru.chikalin.textdecal/Shaders/LiberationSans Decals SDF.asset.meta

@@ -0,0 +1,8 @@
+fileFormatVersion: 2
+guid: 9d2d7c952bc8c4e968019a926227e17b
+NativeFormatImporter:
+  externalObjects: {}
+  mainObjectFileID: 0
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/ru.chikalin.textdecal/Shaders/TMP_SDF-Mobile SSD Decal.shader

@@ -0,0 +1,106 @@
+// Simplified SDF shader:
+// - No Shading Option (bevel / bump / env map)
+// - No Glow Option
+// - Softness is applied on both side of the outline
+
+Shader "TextMeshPro/Mobile/Decal/Distance Field SSD" {
+
+Properties {
+	_FaceColor		    ("Face Color", Color) = (1,1,1,1)
+	_FaceDilate			("Face Dilate", Range(-1,1)) = 0
+
+	_OutlineColor	    ("Outline Color", Color) = (0,0,0,1)
+	_OutlineWidth		("Outline Thickness", Range(0,1)) = 0
+	_OutlineSoftness	("Outline Softness", Range(0,1)) = 0
+
+	_UnderlayColor		("Border Color", Color) = (0,0,0,.5)
+	_UnderlayOffsetX 	("Border OffsetX", Range(-1,1)) = 0
+	_UnderlayOffsetY 	("Border OffsetY", Range(-1,1)) = 0
+	_UnderlayDilate		("Border Dilate", Range(-1,1)) = 0
+	_UnderlaySoftness 	("Border Softness", Range(0,1)) = 0
+
+	_WeightNormal		("Weight Normal", float) = 0
+	_WeightBold			("Weight Bold", float) = .5
+
+	_ShaderFlags		("Flags", float) = 0
+	_ScaleRatioA		("Scale RatioA", float) = 1
+	_ScaleRatioB		("Scale RatioB", float) = 1
+	_ScaleRatioC		("Scale RatioC", float) = 1
+
+	_MainTex			("Font Atlas", 2D) = "white" {}
+	_TextureWidth		("Texture Width", float) = 512
+	_TextureHeight		("Texture Height", float) = 512
+	_GradientScale		("Gradient Scale", float) = 5
+	_ScaleX				("Scale X", float) = 1
+	_ScaleY				("Scale Y", float) = 1
+	_PerspectiveFilter	("Perspective Correction", Range(0, 1)) = 0.875
+	_Sharpness			("Sharpness", Range(-1,1)) = 0
+
+	_VertexOffsetX		("Vertex OffsetX", float) = 0
+	_VertexOffsetY		("Vertex OffsetY", float) = 0
+
+	_ClipRect			("Clip Rect", vector) = (-32767, -32767, 32767, 32767)
+	_MaskSoftnessX		("Mask SoftnessX", float) = 0
+	_MaskSoftnessY		("Mask SoftnessY", float) = 0
+	_MaskTex			("Mask Texture", 2D) = "white" {}
+	_MaskInverse		("Inverse", float) = 0
+	_MaskEdgeColor		("Edge Color", Color) = (1,1,1,1)
+	_MaskEdgeSoftness	("Edge Softness", Range(0, 1)) = 0.01
+	_MaskWipeControl	("Wipe Position", Range(0, 1)) = 0.5
+
+	_StencilComp		("Stencil Comparison", Float) = 8
+	_Stencil			("Stencil ID", Float) = 0
+	_StencilOp			("Stencil Operation", Float) = 0
+	_StencilWriteMask	("Stencil Write Mask", Float) = 255
+	_StencilReadMask	("Stencil Read Mask", Float) = 255
+
+    _CullMode           ("Cull Mode", Float) = 0
+	_ColorMask			("Color Mask", Float) = 15
+}
+
+SubShader {
+	Tags {
+		"Queue"="Transparent"
+		"IgnoreProjector"="True"
+		"RenderType"="Transparent"
+	}
+
+	Stencil
+	{
+		Ref [_Stencil]
+		Comp [_StencilComp]
+		Pass [_StencilOp]
+		ReadMask [_StencilReadMask]
+		WriteMask [_StencilWriteMask]
+	}
+
+	Cull [_CullMode]
+	ZWrite Off
+	Lighting Off
+	Fog { Mode Off }
+	ZTest [unity_GUIZTestMode]
+	Blend One OneMinusSrcAlpha
+	ColorMask [_ColorMask]
+
+	Pass {
+		HLSLPROGRAM
+		#pragma vertex VertShader
+		#pragma fragment PixShader
+		#pragma shader_feature __ OUTLINE_ON
+		#pragma shader_feature __ UNDERLAY_ON UNDERLAY_INNER
+
+		#pragma multi_compile __ UNITY_UI_CLIP_RECT
+		#pragma multi_compile __ UNITY_UI_ALPHACLIP
+		
+		// #include "UnityCG.cginc"
+		// #include "UnityUI.cginc"
+		#include "TMPro_Properties.cginc"
+
+		#include "TMPro_Decal.cginc"
+
+		ENDHLSL
+	}
+}
+
+CustomEditor "TMPro.EditorUtilities.TMP_SDFShaderGUI"
+}

Assets/ru.chikalin.textdecal/Shaders/TMP_SDF-Mobile SSD Decal.shader.meta

@@ -0,0 +1,3 @@
+fileFormatVersion: 2
+guid: 970b94dd738345c3ab1ac4418c017ad4
+timeCreated: 1731679485

Assets/ru.chikalin.textdecal/Shaders/TMP_SDF-Mobile-Decal.shader

@@ -0,0 +1,301 @@
+// Simplified SDF shader:
+// - No Shading Option (bevel / bump / env map)
+// - No Glow Option
+// - Softness is applied on both side of the outline
+
+Shader "TextMeshPro/Mobile/Distance Field/Decal Text" {
+
+Properties {
+	[HDR]_FaceColor     ("Face Color", Color) = (1,1,1,1)
+	_Color     ("Color", Color) = (1,1,1,1)
+	_FaceDilate			("Face Dilate", Range(-1,1)) = 0
+
+	[HDR]_OutlineColor	("Outline Color", Color) = (0,0,0,1)
+	_OutlineWidth		("Outline Thickness", Range(0,1)) = 0
+	_OutlineSoftness	("Outline Softness", Range(0,1)) = 0
+
+	[HDR]_UnderlayColor	("Border Color", Color) = (0,0,0,.5)
+	_UnderlayOffsetX 	("Border OffsetX", Range(-1,1)) = 0
+	_UnderlayOffsetY 	("Border OffsetY", Range(-1,1)) = 0
+	_UnderlayDilate		("Border Dilate", Range(-1,1)) = 0
+	_UnderlaySoftness 	("Border Softness", Range(0,1)) = 0
+
+	_WeightNormal		("Weight Normal", float) = 0
+	_WeightBold			("Weight Bold", float) = .5
+
+	_ShaderFlags		("Flags", float) = 0
+	_ScaleRatioA		("Scale RatioA", float) = 1
+	_ScaleRatioB		("Scale RatioB", float) = 1
+	_ScaleRatioC		("Scale RatioC", float) = 1
+
+	_MainTex			("Font Atlas", 2D) = "white" {}
+	_TextureWidth		("Texture Width", float) = 512
+	_TextureHeight		("Texture Height", float) = 512
+	_GradientScale		("Gradient Scale", float) = 5
+	_ScaleX				("Scale X", float) = 1
+	_ScaleY				("Scale Y", float) = 1
+	_PerspectiveFilter	("Perspective Correction", Range(0, 1)) = 0.875
+	_Sharpness			("Sharpness", Range(-1,1)) = 0
+
+	_VertexOffsetX		("Vertex OffsetX", float) = 0
+	_VertexOffsetY		("Vertex OffsetY", float) = 0
+
+	_ClipRect			("Clip Rect", vector) = (-32767, -32767, 32767, 32767)
+	_MaskSoftnessX		("Mask SoftnessX", float) = 0
+	_MaskSoftnessY		("Mask SoftnessY", float) = 0
+
+	_StencilComp		("Stencil Comparison", Float) = 8
+	_Stencil			("Stencil ID", Float) = 0
+	_StencilOp			("Stencil Operation", Float) = 0
+	_StencilWriteMask	("Stencil Write Mask", Float) = 255
+	_StencilReadMask	("Stencil Read Mask", Float) = 255
+
+	_CullMode			("Cull Mode", Float) = 0
+	_ColorMask			("Color Mask", Float) = 15
+}
+
+SubShader {
+	Tags
+	{
+		"Queue"="Transparent"
+		"IgnoreProjector"="True"
+		"RenderType"="Transparent"
+	}
+
+
+	Stencil
+	{
+		Ref [_Stencil]
+		Comp [_StencilComp]
+		Pass [_StencilOp]
+		ReadMask [_StencilReadMask]
+		WriteMask [_StencilWriteMask]
+	}
+
+	Cull [_CullMode]
+	ZWrite Off
+	Lighting Off
+	Fog { Mode Off }
+	ZTest [unity_GUIZTestMode]
+	Blend One OneMinusSrcAlpha
+	ColorMask [_ColorMask]
+
+	Pass {
+		HLSLPROGRAM
+		#pragma vertex VertShader
+		#pragma fragment PixShader
+		#pragma shader_feature __ OUTLINE_ON
+		#pragma shader_feature __ UNDERLAY_ON UNDERLAY_INNER
+
+		#pragma multi_compile __ UNITY_UI_CLIP_RECT
+		#pragma multi_compile __ UNITY_UI_ALPHACLIP
+
+		#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareDepthTexture.hlsl"
+		#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
+
+		CBUFFER_START(UnityPerMaterial)
+			uniform float4 _Color;
+			#include "TMPro_Properties.cginc"
+		CBUFFER_END
+		
+		struct vertex_t {
+			UNITY_VERTEX_INPUT_INSTANCE_ID
+			float3	vertex			: POSITION;
+			float3	normal			: NORMAL;
+			float4	color			: COLOR;
+			float2	texcoord0		: TEXCOORD0;
+			float2	texcoord1		: TEXCOORD1;
+			float2 texcoord3 : TEXCOORD3; // vertex left bottom position
+			float2 texcoord4 : TEXCOORD4; // UV left bottom position
+			float2 texcoord5 : TEXCOORD5; // vertex width, height
+			float2 texcoord6 : TEXCOORD6; // UV width, height
+			float2 texcoord7 : TEXCOORD7; // rotation (x - angle)
+		};
+
+		struct pixel_t {
+			UNITY_VERTEX_INPUT_INSTANCE_ID
+			UNITY_VERTEX_OUTPUT_STEREO
+			float4	vertex			: SV_POSITION;
+			float4	faceColor		: COLOR;
+			float4	outlineColor	: COLOR1;
+			float4	texcoord0		: TEXCOORD0;			// Texture UV, Mask UV
+			half4	param			: TEXCOORD1;			// Scale(x), BiasIn(y), BiasOut(z), Bias(w)
+			half4	mask			: TEXCOORD2;			// Position in clip space(xy), Softness(zw)
+			#if (UNDERLAY_ON | UNDERLAY_INNER)
+			float4	texcoord1		: TEXCOORD3;			// Texture UV, alpha, reserved
+			half2	underlayParam	: TEXCOORD4;			// Scale(x), Bias(y)
+			#endif
+			float4 vert_data : TEXCOORD5; // vertex left bottom position (x, y), vertex width (z), height (w)
+			float4 uv_data : TEXCOORD6; // UV left bottom position (x, y), UV width (z), height (w)
+			float2 rot_data : TEXCOORD7; // sin(a), cos(a)
+		};
+
+
+		pixel_t VertShader(vertex_t input)
+		{
+			pixel_t output = (pixel_t)0;
+
+			UNITY_SETUP_INSTANCE_ID(input);
+			UNITY_TRANSFER_INSTANCE_ID(input, output);
+			UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
+
+			float bold = step(input.texcoord1.y, 0);
+
+			float3 vert = input.vertex;
+			vert.x += _VertexOffsetX;
+			vert.y += _VertexOffsetY;
+			float4 vPosition = GetVertexPositionInputs(input.vertex).positionCS;
+
+			float2 pixelSize = vPosition.w;
+			pixelSize /= float2(_ScaleX, _ScaleY) * abs(mul((float2x2)UNITY_MATRIX_P, _ScreenParams.xy));
+
+			float scale = rsqrt(dot(pixelSize, pixelSize));
+			scale *= abs(input.texcoord1.y) * _GradientScale * (_Sharpness + 1);
+			if(UNITY_MATRIX_P[3][3] == 0) scale = lerp(abs(scale) * (1 - _PerspectiveFilter), scale, abs(dot(TransformObjectToWorld(input.normal.xyz), normalize(TransformWorldToViewDir(vert)))));
+
+			float weight = lerp(_WeightNormal, _WeightBold, bold) / 4.0;
+			weight = (weight + _FaceDilate) * _ScaleRatioA * 0.5;
+
+			float layerScale = scale;
+
+			scale /= 1 + (_OutlineSoftness * _ScaleRatioA * scale);
+			float bias = (0.5 - weight) * scale - 0.5;
+			float outline = _OutlineWidth * _ScaleRatioA * 0.5 * scale;
+
+			float opacity = input.color.a;
+			#if (UNDERLAY_ON | UNDERLAY_INNER)
+			opacity = 1.0;
+			#endif
+			
+			_FaceColor.a = min(_FaceColor.a, _Color.a);
+			float4 faceColor = float4(input.color.rgb, opacity) * _FaceColor;
+			faceColor.rgb *= faceColor.a;
+
+			float4 outlineColor = _OutlineColor;
+			outlineColor.a *= opacity;
+			outlineColor.rgb *= outlineColor.a;
+			outlineColor = lerp(faceColor, outlineColor, sqrt(min(1.0, (outline * 2))));
+
+			#if (UNDERLAY_ON | UNDERLAY_INNER)
+			layerScale /= 1 + ((_UnderlaySoftness * _ScaleRatioC) * layerScale);
+			float layerBias = (.5 - weight) * layerScale - .5 - ((_UnderlayDilate * _ScaleRatioC) * .5 * layerScale);
+
+			float x = -(_UnderlayOffsetX * _ScaleRatioC) * _GradientScale / _TextureWidth;
+			float y = -(_UnderlayOffsetY * _ScaleRatioC) * _GradientScale / _TextureHeight;
+			float2 layerOffset = float2(x, y);
+			#endif
+
+			// Generate UV for the Masking Texture
+			float4 clampedRect = clamp(_ClipRect, -2e10, 2e10);
+			float2 maskUV = (vert.xy - clampedRect.xy) / (clampedRect.zw - clampedRect.xy);
+
+			// Populate structure for pixel shader
+			output.vertex = vPosition;
+			output.faceColor = faceColor;
+			output.outlineColor = outlineColor;
+			output.texcoord0 = float4(input.texcoord0.x, input.texcoord0.y, maskUV.x, maskUV.y);
+			output.param = half4(scale, bias - outline, bias + outline, bias);
+			output.mask = half4(vert.xy * 2 - clampedRect.xy - clampedRect.zw, 0.25 / (0.25 * half2(_MaskSoftnessX, _MaskSoftnessY) + pixelSize.xy));
+			#if (UNDERLAY_ON || UNDERLAY_INNER)
+			output.texcoord1 = float4(input.texcoord0 + layerOffset, input.color.a, 0);
+			output.underlayParam = half2(layerScale, layerBias);
+			#endif
+			output.vert_data = float4(input.texcoord3.xy, input.texcoord5.xy);
+			output.uv_data = float4(input.texcoord4.xy, input.texcoord6.xy);
+			const float angle = input.texcoord7.x;
+			output.rot_data = float2(sin(angle), cos(angle));
+			return output;
+		}
+
+        float invLerp(const float from, const float to, const float value)
+        {
+            return (value - from) / (to - from);
+        }
+
+        float remap(const float origFrom, const float origTo, const float targetFrom, const float targetTo, const float value)
+        {
+	        const float rel = invLerp(origFrom, origTo, value);
+            return lerp(targetFrom, targetTo, rel);
+        }
+
+		float3 rotate(const float3 input, float2 m)
+		{
+			const float c = m.y; // cos(a)
+			const float s = m.x; // sin(a)
+			return mul(input, float3x3(c,-s, 0, s,  c , 0, 0, 0, 1));
+		}
+		
+		// PIXEL SHADER
+		float4 PixShader(pixel_t input) : SV_Target
+		{
+			UNITY_SETUP_INSTANCE_ID(input);
+
+			// decal start
+			const float2 uv = (input.vertex.xy / _ScaledScreenParams.xy);
+            #if UNITY_REVERSED_Z
+				float depth = SampleSceneDepth(uv);
+            #else
+             // Adjust Z to match NDC for OpenGL ([-1, 1])
+				float depth = lerp(UNITY_NEAR_CLIP_VALUE, 1, SampleSceneDepth(uv));
+            #endif
+            const float3 world_pos = ComputeWorldSpacePosition(uv, depth, UNITY_MATRIX_I_VP);
+            float3 local_pos = TransformWorldToObject(world_pos);
+			// move local space to left bottom vertex position
+            local_pos -= float3(input.vert_data.xy, 0);
+			local_pos = rotate(local_pos,input.rot_data);
+			
+            const float width = input.vert_data.z;
+            const float height = input.vert_data.w;
+			float4 decal_clip = float4(0, 0, 1, 1);
+			decal_clip.x = step(0, local_pos.x) * (1 - step(width, local_pos.x));
+			decal_clip.y = step(0, local_pos.y) * (1 - step(height, local_pos.y));
+			
+			// remap from (0..vertex_size) to (uv.start..uv.end)
+			local_pos.x = remap(0, width, input.uv_data.x, input.uv_data.x + input.uv_data.z, local_pos.x);
+			local_pos.y = remap(0, height, input.uv_data.y, input.uv_data.y + input.uv_data.w, local_pos.y);
+			// decal end
+
+			// half d = tex2D(_MainTex, input.texcoord0.xy).a * input.param.x;
+			half d = tex2D(_MainTex, local_pos.xy).a * input.param.x;
+            half4 c = input.faceColor * saturate(d - input.param.w);
+			
+			c *= decal_clip.x * decal_clip.y * decal_clip.z;
+			
+			#ifdef OUTLINE_ON
+			c = lerp(input.outlineColor, input.faceColor, saturate(d - input.param.z));
+			c *= saturate(d - input.param.y);
+			#endif
+
+			#if UNDERLAY_ON
+			d = tex2D(_MainTex, input.texcoord1.xy).a * input.underlayParam.x;
+			c += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * saturate(d - input.underlayParam.y) * (1 - c.a);
+			#endif
+
+			#if UNDERLAY_INNER
+			half sd = saturate(d - input.param.z);
+			d = tex2D(_MainTex, input.texcoord1.xy).a * input.underlayParam.x;
+			c += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * (1 - saturate(d - input.underlayParam.y)) * sd * (1 - c.a);
+			#endif
+
+			// Alternative implementation to UnityGet2DClipping with support for softness.
+			#if UNITY_UI_CLIP_RECT
+			half2 m = saturate((_ClipRect.zw - _ClipRect.xy - abs(input.mask.xy)) * input.mask.zw);
+			c *= m.x * m.y;
+			#endif
+
+			#if (UNDERLAY_ON | UNDERLAY_INNER)
+			c *= input.texcoord1.z;
+			#endif
+
+			#if UNITY_UI_ALPHACLIP
+			clip(c.a - 0.001);
+			#endif
+			
+			return c;
+		}
+		ENDHLSL
+	}
+}
+
+CustomEditor "TMPro.EditorUtilities.TMP_SDFShaderGUI"
+}

Assets/ru.chikalin.textdecal/Shaders/TMP_SDF-Mobile-Decal.shader.meta

@@ -0,0 +1,9 @@
+fileFormatVersion: 2
+guid: c47dfb763ac2d4f838ac57291e49f2d8
+ShaderImporter:
+  externalObjects: {}
+  defaultTextures: []
+  nonModifiableTextures: []
+  userData: 
+  assetBundleName: 
+  assetBundleVariant: 

Assets/ru.chikalin.textdecal/Shaders/TMPro_Decal.cginc

@@ -0,0 +1,227 @@
+#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareDepthTexture.hlsl"
+#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
+#include <HLSLSupport.cginc>
+
+struct vertex_t
+{
+    UNITY_VERTEX_INPUT_INSTANCE_ID
+    float4	position		: POSITION;
+    float3	normal			: NORMAL;
+    float4	color			: COLOR;
+    float4	texcoord0		: TEXCOORD0;
+    float2	texcoord1		: TEXCOORD1;
+    float2 texcoord3 : TEXCOORD3; // vertex left bottom position
+    float2 texcoord4 : TEXCOORD4; // UV left bottom position
+    float2 texcoord5 : TEXCOORD5; // vertex width, height
+    float2 texcoord6 : TEXCOORD6; // UV width, height
+    float2 texcoord7 : TEXCOORD7; // rotation (x - angle)
+};
+
+struct pixel_t
+{
+    UNITY_VERTEX_INPUT_INSTANCE_ID
+    UNITY_VERTEX_OUTPUT_STEREO
+    float4	position		: SV_POSITION;
+    float4	faceColor		: COLOR;
+    float4	outlineColor	: COLOR1;
+    float4	texcoord0		: TEXCOORD0;			
+    float4	param			: TEXCOORD1;			// x = weight, y = no longer used
+    float2	mask			: TEXCOORD2;			
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    float4	texcoord1		: TEXCOORD3;		
+    float2	underlayParam	: TEXCOORD4;			
+    #endif
+    float4 vert_data : TEXCOORD5; // vertex left bottom position (x, y), vertex width (z), height (w)
+    float4 uv_data : TEXCOORD6; // UV left bottom position (x, y), UV width (z), height (w)
+    float2 rot_data : TEXCOORD7; // sin(a), cos(a)
+};
+
+float4 SRGBToLinear(float4 rgba)
+{
+    return float4(lerp(rgba.rgb / 12.92f, pow((rgba.rgb + 0.055f) / 1.055f, 2.4f), step(0.04045f, rgba.rgb)), rgba.a);
+}
+
+float _UIMaskSoftnessX;
+float _UIMaskSoftnessY;
+
+pixel_t VertShader(vertex_t input)
+{
+    pixel_t output;
+
+    UNITY_INITIALIZE_OUTPUT(pixel_t, output);
+    UNITY_SETUP_INSTANCE_ID(input);
+    UNITY_TRANSFER_INSTANCE_ID(input, output);
+    UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
+
+    float bold = step(input.texcoord0.w, 0);
+
+    float4 vert = input.position;
+    vert.x += _VertexOffsetX;
+    vert.y += _VertexOffsetY;
+
+    float4 vPosition = GetVertexPositionInputs(vert).positionCS;
+
+    float weight = lerp(_WeightNormal, _WeightBold, bold) / 4.0;
+    weight = (weight + _FaceDilate) * _ScaleRatioA * 0.5;
+
+    // Generate UV for the Masking Texture
+    float4 clampedRect = clamp(_ClipRect, -2e10, 2e10);
+    float2 maskUV = (vert.xy - clampedRect.xy) / (clampedRect.zw - clampedRect.xy);
+
+    float4 color = input.color;
+    #if (FORCE_LINEAR && !UNITY_COLORSPACE_GAMMA)
+    color = SRGBToLinear(input.color);
+    #endif
+
+    float opacity = color.a;
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    opacity = 1.0;
+    #endif
+
+    float4 faceColor = float4(color.rgb, opacity) * _FaceColor;
+    faceColor.rgb *= faceColor.a;
+
+    float4 outlineColor = _OutlineColor;
+    outlineColor.a *= opacity;
+    outlineColor.rgb *= outlineColor.a;
+
+    output.position = vPosition;
+    output.faceColor = faceColor;
+    output.outlineColor = outlineColor;
+    output.texcoord0 = float4(input.texcoord0.xy, maskUV.xy);
+    output.param = float4(0.5 - weight, 0, _OutlineWidth * _ScaleRatioA * 0.5, 0);
+
+    float2 mask = float2(0, 0);
+    #if UNITY_UI_CLIP_RECT
+    mask = vert.xy * 2 - clampedRect.xy - clampedRect.zw;
+    #endif
+    output.mask = mask;
+
+    #if (UNDERLAY_ON || UNDERLAY_INNER)
+    float4 underlayColor = _UnderlayColor;
+    underlayColor.rgb *= underlayColor.a;
+
+    float x = -(_UnderlayOffsetX * _ScaleRatioC) * _GradientScale / _TextureWidth;
+    float y = -(_UnderlayOffsetY * _ScaleRatioC) * _GradientScale / _TextureHeight;
+
+    output.texcoord2 = float4(input.texcoord0 + float2(x, y), input.color.a, 0);
+    output.underlayColor = underlayColor;
+    #endif
+
+    // decal
+    output.vert_data = float4(input.texcoord3.xy, input.texcoord5.xy);
+    output.uv_data = float4(input.texcoord4.xy, input.texcoord6.xy);
+    const float angle = input.texcoord7.x;
+    output.rot_data = float2(sin(angle), cos(angle));
+    
+    return output;
+}
+
+float invLerp(const float from, const float to, const float value)
+{
+    return (value - from) / (to - from);
+}
+
+float remap(const float origFrom, const float origTo, const float targetFrom, const float targetTo, const float value)
+{
+    const float rel = invLerp(origFrom, origTo, value);
+    return lerp(targetFrom, targetTo, rel);
+}
+
+float3 rotate(const float3 input, float2 m)
+{
+    const float c = m.y; // cos(a)
+    const float s = m.x; // sin(a)
+    return mul(input, float3x3(c,-s, 0, s,  c , 0, 0, 0, 1));
+}
+
+float4 PixShader(pixel_t input) : SV_Target
+{
+    UNITY_SETUP_INSTANCE_ID(input);
+    
+    // decal start
+    const float2 uv = (input.position.xy / _ScaledScreenParams.xy);
+    #if UNITY_REVERSED_Z
+    float depth = SampleSceneDepth(uv);
+    #else
+    // Adjust Z to match NDC for OpenGL ([-1, 1])
+    float depth = lerp(UNITY_NEAR_CLIP_VALUE, 1, SampleSceneDepth(uv));
+    #endif
+    const float3 world_pos = ComputeWorldSpacePosition(uv, depth, UNITY_MATRIX_I_VP);
+    float3 local_pos = TransformWorldToObject(world_pos);
+    // move local space to left bottom vertex position
+    local_pos -= float3(input.vert_data.xy, 0);
+    local_pos = rotate(local_pos,input.rot_data);
+    const float width = input.vert_data.z;
+    const float height = input.vert_data.w;
+    float4 decal_clip = float4(0, 0, 1, 1);
+    decal_clip.x = step(0, local_pos.x) * (1 - step(width, local_pos.x));
+    decal_clip.y = step(0, local_pos.y) * (1 - step(height, local_pos.y));
+			
+    // remap from (0..vertex_size) to (uv.start..uv.end)
+    local_pos.x = remap(0, width, input.uv_data.x, input.uv_data.x + input.uv_data.z, local_pos.x);
+    local_pos.y = remap(0, height, input.uv_data.y, input.uv_data.y + input.uv_data.w, local_pos.y);
+    // decal end
+    
+    // float d = tex2D(_MainTex, input.texcoord0.xy).a;
+    float d = tex2D(_MainTex, local_pos.xy).a;
+
+    float pixelSize = abs(ddx(input.texcoord0.y)) + abs(ddy(input.texcoord0.y));
+    pixelSize *= _TextureHeight * 0.75;
+    float scale = 1 / pixelSize * _GradientScale * (_Sharpness + 1);
+
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    float layerScale = scale;
+    layerScale /= 1 + ((_UnderlaySoftness * _ScaleRatioC) * layerScale);
+    float layerBias = input.param.x * layerScale - .5 - ((_UnderlayDilate * _ScaleRatioC) * .5 * layerScale);
+    #endif
+
+    // scale /= 1 + (_OutlineSoftness * _ScaleRatioA * scale);
+
+    float4 faceColor = input.faceColor * saturate((d - input.param.x) * scale + 0.5);
+    faceColor *= decal_clip.x * decal_clip.y * decal_clip.z;
+			
+    #if OUTLINE_ON
+    float4 outlineColor = lerp(input.faceColor, input.outlineColor, sqrt(min(1.0, input.param.z * scale * 2)));
+    faceColor = lerp(outlineColor, input.faceColor, saturate((d - input.param.x - input.param.z) * scale + 0.5));
+    faceColor *= saturate((d - input.param.x + input.param.z) * scale + 0.5);
+    #endif
+
+    #if UNDERLAY_ON
+    d = tex2D(_MainTex, input.texcoord2.xy).a * layerScale;
+    faceColor += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * saturate(d - layerBias) * (1 - faceColor.a);
+    #endif
+
+    #if UNDERLAY_INNER
+    float bias = input.param.x * scale - 0.5;
+    float sd = saturate(d * scale - bias - input.param.z);
+    d = tex2D(_MainTex, input.texcoord2.xy).a * layerScale;
+    faceColor += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * (1 - saturate(d - layerBias)) * sd * (1 - faceColor.a);
+    #endif
+
+    #if MASKING
+    float a = abs(_MaskInverse - tex2D(_MaskTex, input.texcoord0.zw).a);
+    float t = a + (1 - _MaskWipeControl) * _MaskEdgeSoftness - _MaskWipeControl;
+    a = saturate(t / _MaskEdgeSoftness);
+    faceColor.rgb = lerp(_MaskEdgeColor.rgb * faceColor.a, faceColor.rgb, a);
+    faceColor *= a;
+    #endif
+
+    // Alternative implementation to UnityGet2DClipping with support for softness
+    #if UNITY_UI_CLIP_RECT
+    half2 maskSoftness = half2(max(_UIMaskSoftnessX, _MaskSoftnessX), max(_UIMaskSoftnessY, _MaskSoftnessY));
+    float2 maskZW = 0.25 / (0.25 * maskSoftness + 1 / scale);
+    float2 m = saturate((_ClipRect.zw - _ClipRect.xy - abs(input.mask.xy)) * maskZW);
+    faceColor *= m.x * m.y;
+    #endif
+
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    faceColor *= input.texcoord2.z;
+    #endif
+
+    #if UNITY_UI_ALPHACLIP
+    clip(faceColor.a - 0.001);
+    #endif
+
+    return faceColor;
+}

Assets/ru.chikalin.textdecal/Shaders/TMPro_Decal.cginc.meta

@@ -0,0 +1,3 @@
+fileFormatVersion: 2
+guid: 83b6a32242774237aba4e25f0535f2a5
+timeCreated: 1731679606

Assets/ru.chikalin.textdecal/Shaders/TMPro_Mobile.cginc

@@ -0,0 +1,167 @@
+#include <HLSLSupport.cginc>
+
+struct vertex_t
+{
+    UNITY_VERTEX_INPUT_INSTANCE_ID
+    float4	position		: POSITION;
+    float3	normal			: NORMAL;
+    float4	color			: COLOR;
+    float4	texcoord0		: TEXCOORD0;
+    float2	texcoord1		: TEXCOORD1;
+};
+
+struct pixel_t
+{
+    UNITY_VERTEX_INPUT_INSTANCE_ID
+    UNITY_VERTEX_OUTPUT_STEREO
+    float4	position		: SV_POSITION;
+    float4	faceColor		: COLOR;
+    float4	outlineColor	: COLOR1;
+    float4	texcoord0		: TEXCOORD0;
+    float4	param			: TEXCOORD1;		// x = weight, y = no longer used
+    float2	mask			: TEXCOORD2;
+    #if (UNDERLAY_ON || UNDERLAY_INNER)
+    float4	texcoord2		: TEXCOORD3;
+    float4	underlayColor	: COLOR2;
+    #endif
+};
+
+float4 SRGBToLinear(float4 rgba)
+{
+    return float4(lerp(rgba.rgb / 12.92f, pow((rgba.rgb + 0.055f) / 1.055f, 2.4f), step(0.04045f, rgba.rgb)), rgba.a);
+}
+
+float _UIMaskSoftnessX;
+float _UIMaskSoftnessY;
+
+pixel_t VertShader(vertex_t input)
+{
+    pixel_t output;
+
+    UNITY_INITIALIZE_OUTPUT(pixel_t, output);
+    UNITY_SETUP_INSTANCE_ID(input);
+    UNITY_TRANSFER_INSTANCE_ID(input, output);
+    UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
+
+    float bold = step(input.texcoord0.w, 0);
+
+    float4 vert = input.position;
+    vert.x += _VertexOffsetX;
+    vert.y += _VertexOffsetY;
+
+    float4 vPosition = UnityObjectToClipPos(vert);
+
+    float weight = lerp(_WeightNormal, _WeightBold, bold) / 4.0;
+    weight = (weight + _FaceDilate) * _ScaleRatioA * 0.5;
+
+    // Generate UV for the Masking Texture
+    float4 clampedRect = clamp(_ClipRect, -2e10, 2e10);
+    float2 maskUV = (vert.xy - clampedRect.xy) / (clampedRect.zw - clampedRect.xy);
+
+    float4 color = input.color;
+    #if (FORCE_LINEAR && !UNITY_COLORSPACE_GAMMA)
+    color = SRGBToLinear(input.color);
+    #endif
+
+    float opacity = color.a;
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    opacity = 1.0;
+    #endif
+
+    float4 faceColor = float4(color.rgb, opacity) * _FaceColor;
+    faceColor.rgb *= faceColor.a;
+
+    float4 outlineColor = _OutlineColor;
+    outlineColor.a *= opacity;
+    outlineColor.rgb *= outlineColor.a;
+
+    output.position = vPosition;
+    output.faceColor = faceColor;
+    output.outlineColor = outlineColor;
+    output.texcoord0 = float4(input.texcoord0.xy, maskUV.xy);
+    output.param = float4(0.5 - weight, 0, _OutlineWidth * _ScaleRatioA * 0.5, 0);
+
+    float2 mask = float2(0, 0);
+    #if UNITY_UI_CLIP_RECT
+    mask = vert.xy * 2 - clampedRect.xy - clampedRect.zw;
+    #endif
+    output.mask = mask;
+
+    #if (UNDERLAY_ON || UNDERLAY_INNER)
+    float4 underlayColor = _UnderlayColor;
+    underlayColor.rgb *= underlayColor.a;
+
+    float x = -(_UnderlayOffsetX * _ScaleRatioC) * _GradientScale / _TextureWidth;
+    float y = -(_UnderlayOffsetY * _ScaleRatioC) * _GradientScale / _TextureHeight;
+
+    output.texcoord2 = float4(input.texcoord0 + float2(x, y), input.color.a, 0);
+    output.underlayColor = underlayColor;
+    #endif
+
+    return output;
+}
+
+float4 PixShader(pixel_t input) : SV_Target
+{
+    UNITY_SETUP_INSTANCE_ID(input);
+
+    float d = tex2D(_MainTex, input.texcoord0.xy).a;
+
+    float pixelSize = abs(ddx(input.texcoord0.y)) + abs(ddy(input.texcoord0.y));
+    pixelSize *= _TextureHeight * 0.75;
+    float scale = 1 / pixelSize * _GradientScale * (_Sharpness + 1);
+
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    float layerScale = scale;
+    layerScale /= 1 + ((_UnderlaySoftness * _ScaleRatioC) * layerScale);
+    float layerBias = input.param.x * layerScale - .5 - ((_UnderlayDilate * _ScaleRatioC) * .5 * layerScale);
+    #endif
+
+    scale /= 1 + (_OutlineSoftness * _ScaleRatioA * scale);
+
+    float4 faceColor = input.faceColor * saturate((d - input.param.x) * scale + 0.5);
+
+    #if OUTLINE_ON
+    float4 outlineColor = lerp(input.faceColor, input.outlineColor, sqrt(min(1.0, input.param.z * scale * 2)));
+    faceColor = lerp(outlineColor, input.faceColor, saturate((d - input.param.x - input.param.z) * scale + 0.5));
+    faceColor *= saturate((d - input.param.x + input.param.z) * scale + 0.5);
+    #endif
+
+    #if UNDERLAY_ON
+    d = tex2D(_MainTex, input.texcoord2.xy).a * layerScale;
+    faceColor += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * saturate(d - layerBias) * (1 - faceColor.a);
+    #endif
+
+    #if UNDERLAY_INNER
+    float bias = input.param.x * scale - 0.5;
+    float sd = saturate(d * scale - bias - input.param.z);
+    d = tex2D(_MainTex, input.texcoord2.xy).a * layerScale;
+    faceColor += float4(_UnderlayColor.rgb * _UnderlayColor.a, _UnderlayColor.a) * (1 - saturate(d - layerBias)) * sd * (1 - faceColor.a);
+    #endif
+
+    #if MASKING
+    float a = abs(_MaskInverse - tex2D(_MaskTex, input.texcoord0.zw).a);
+    float t = a + (1 - _MaskWipeControl) * _MaskEdgeSoftness - _MaskWipeControl;
+    a = saturate(t / _MaskEdgeSoftness);
+    faceColor.rgb = lerp(_MaskEdgeColor.rgb * faceColor.a, faceColor.rgb, a);
+    faceColor *= a;
+    #endif
+
+    // Alternative implementation to UnityGet2DClipping with support for softness
+    #if UNITY_UI_CLIP_RECT
+    half2 maskSoftness = half2(max(_UIMaskSoftnessX, _MaskSoftnessX), max(_UIMaskSoftnessY, _MaskSoftnessY));
+    float2 maskZW = 0.25 / (0.25 * maskSoftness + 1 / scale);
+    float2 m = saturate((_ClipRect.zw - _ClipRect.xy - abs(input.mask.xy)) * maskZW);
+    faceColor *= m.x * m.y;
+    #endif
+
+    #if (UNDERLAY_ON | UNDERLAY_INNER)
+    faceColor *= input.texcoord2.z;
+    #endif
+
+    #if UNITY_UI_ALPHACLIP
+    clip(faceColor.a - 0.001);
+    #endif
+
+    return faceColor;
+}

Assets/ru.chikalin.textdecal/Shaders/TMPro_Mobile.cginc.meta

@@ -0,0 +1,3 @@
+fileFormatVersion: 2
+guid: 5c3c90976a974ebfab085411aba35ac1
+timeCreated: 1731679510

Assets/ru.chikalin.textdecal/Shaders/TMPro_Properties.cginc

@@ -0,0 +1,80 @@
+// UI Editable properties
+uniform sampler2D	_FaceTex;					// Alpha : Signed Distance
+uniform float		_FaceUVSpeedX;
+uniform float		_FaceUVSpeedY;
+uniform float4		_FaceColor;					// RGBA : Color + Opacity
+uniform float		_FaceDilate;				// v[ 0, 1]
+uniform float		_OutlineSoftness;			// v[ 0, 1]
+
+uniform sampler2D	_OutlineTex;				// RGBA : Color + Opacity
+uniform float		_OutlineUVSpeedX;
+uniform float		_OutlineUVSpeedY;
+uniform float4		_OutlineColor;				// RGBA : Color + Opacity
+uniform float		_OutlineWidth;				// v[ 0, 1]
+
+uniform float		_Bevel;						// v[ 0, 1]
+uniform float		_BevelOffset;				// v[-1, 1]
+uniform float		_BevelWidth;				// v[-1, 1]
+uniform float		_BevelClamp;				// v[ 0, 1]
+uniform float		_BevelRoundness;			// v[ 0, 1]
+
+uniform sampler2D	_BumpMap;					// Normal map
+uniform float		_BumpOutline;				// v[ 0, 1]
+uniform float		_BumpFace;					// v[ 0, 1]
+
+uniform samplerCUBE	_Cube;						// Cube / sphere map
+uniform float4 		_ReflectFaceColor;			// RGB intensity
+uniform float4		_ReflectOutlineColor;
+//uniform float		_EnvTiltX;					// v[-1, 1]
+//uniform float		_EnvTiltY;					// v[-1, 1]
+uniform float3      _EnvMatrixRotation;
+uniform float4x4	_EnvMatrix;
+
+uniform float4		_SpecularColor;				// RGB intensity
+uniform float		_LightAngle;				// v[ 0,Tau]
+uniform float		_SpecularPower;				// v[ 0, 1]
+uniform float		_Reflectivity;				// v[ 5, 15]
+uniform float		_Diffuse;					// v[ 0, 1]
+uniform float		_Ambient;					// v[ 0, 1]
+
+uniform float4		_UnderlayColor;				// RGBA : Color + Opacity
+uniform float		_UnderlayOffsetX;			// v[-1, 1]
+uniform float		_UnderlayOffsetY;			// v[-1, 1]
+uniform float		_UnderlayDilate;			// v[-1, 1]
+uniform float		_UnderlaySoftness;			// v[ 0, 1]
+
+uniform float4 		_GlowColor;					// RGBA : Color + Intesity
+uniform float 		_GlowOffset;				// v[-1, 1]
+uniform float 		_GlowOuter;					// v[ 0, 1]
+uniform float 		_GlowInner;					// v[ 0, 1]
+uniform float 		_GlowPower;					// v[ 1, 1/(1+4*4)]
+
+// API Editable properties
+uniform float 		_ShaderFlags;
+uniform float		_WeightNormal;
+uniform float		_WeightBold;
+
+uniform float		_ScaleRatioA;
+uniform float		_ScaleRatioB;
+uniform float		_ScaleRatioC;
+
+uniform float		_VertexOffsetX;
+uniform float		_VertexOffsetY;
+
+//uniform float		_UseClipRect;
+uniform float		_MaskID;
+uniform sampler2D	_MaskTex;
+uniform float4		_MaskCoord;
+uniform float4		_ClipRect;	// bottom left(x,y) : top right(z,w)
+uniform float		_MaskSoftnessX;
+uniform float		_MaskSoftnessY;
+
+// Font Atlas properties
+uniform sampler2D	_MainTex;
+uniform float		_TextureWidth;
+uniform float		_TextureHeight;
+uniform float 		_GradientScale;
+uniform float		_ScaleX;
+uniform float		_ScaleY;
+uniform float		_PerspectiveFilter;
+uniform float		_Sharpness;

Assets/ru.chikalin.textdecal/Shaders/TMPro_Properties.cginc.meta

@@ -0,0 +1,3 @@
+fileFormatVersion: 2
+guid: 49536a91d8d94eddb186152f0eca69a7
+timeCreated: 1731660883